圧電ブザー（電子工作ステーション　¥49）

パッシブブザー（電子工作ステーション　¥42）

#define LED 2
#define BUTTON 3
#define BUZZER 6

bool ledState = false;
int lastButton = HIGH;

void setup() {
  pinMode(LED, OUTPUT);
  pinMode(BUTTON, INPUT_PULLUP);
  startSound();
}

void loop() {
  int nowButton = digitalRead(BUTTON); // 今の状態を読む

  // 「押された瞬間」を見つける（HIGH → LOW）
  if (lastButton == HIGH && nowButton == LOW) {
    ledState = !ledState; // ON/OFFを反転
    delay(50); // チャタリングを防ぐ
  }

  digitalWrite(LED, ledState);

  lastButton = nowButton; // 状態を保存
}

void startSound() {
  tone(BUZZER, 1000, 200);
  delay(500);

  tone(BUZZER, 1000, 200);
  delay(500);

  tone(BUZZER, 1500, 400);
  delay(500);
}

💡 ワンポイント

関数は「処理をまとめた部品」のようなものです。

何度も使う処理や、ひとまとまりにしたい処理を分けて書くことで、プログラムが見やすくなります。

tone(ピン番号, 周波数, 音の長さ)

指定された周波数の信号をピンから出して、音を鳴らします。

音の長さを指定しない場合は、ずっと鳴り続けます（noTone()で止めます）

#define LED 2
#define BUTTON 3
#define BUZZER 6

bool ledState = false;   // LEDの状態（ON/OFF）
int lastButton = HIGH;   // 1回前のボタンの状態
int count = 0;           // 連打カウンター
unsigned long startTime; // 時間を保存

void setup() {
  pinMode(LED, OUTPUT);
  pinMode(BUTTON, INPUT_PULLUP);
  startSound();          // スタート音
  startTime = millis();  // 開始時間を保存
}

💡 ワンポイント

millis() を使うと、マイコンが起動してからの時間（ミリ秒）を取得できます。

1秒 = 1000ミリ秒なので、時間を計るときに便利です。

void loop() {
  if (millis() - startTime < 5000) {      // 5秒以内なら
    int nowButton = digitalRead(BUTTON);

    if (lastButton == HIGH && nowButton == LOW) {
      count++;    // カウントアップ
      delay(50);  // チャタリング防止
    }

    lastButton = nowButton;
  }
  else {
    resultSound(count); // 結果発表
    while (true);       // 終了
  }
}

⏱ ワンポイント

delay() を使わずに時間を測れるのが millis() のポイントです。

プログラムを止めずに時間を管理できるので、ゲームなどに向いています。

⚡ ワンポイント

while (true); は、その場所でずっと止まる命令です。

これ以上プログラムを進めないことで、ゲームを終了させています。

// 結果発表：連打した数だけLEDとブザーでカウント
void resultSound(int c) {
  for (int i = 0; i < c; i++) {

    digitalWrite(LED, HIGH);
    tone(BUZZER, 1200);
    delay(80);

    digitalWrite(LED, LOW);
    noTone(BUZZER);
    delay(80);
  }
}

💡 ワンポイント

引数を使うと、「同じ処理を、違う値で使い回す」ことができます。

今回は、連打回数に応じて音とLEDの回数を変えています。

// 結果発表：連打した数だけLEDとブザーでカウント
void resultSound(int c) {

  int scale[] = {523, 587, 659, 698, 783, 880, 987, 1046};
  int index = 0;
  int size = sizeof(scale) / sizeof(scale[0]);

  for (int i = 0; i < c; i++) {

    digitalWrite(LED, HIGH);
    tone(BUZZER, scale[index]);
    delay(80);

    digitalWrite(LED, LOW);
    noTone(BUZZER);
    delay(80);

    index = (index + 1) % size;
  }
}

🎵 ワンポイント

index = (index + 1) % size; とすることで、最後までいったら最初に戻ります。

これによって、ドレミファソラシドを繰り返すことができます。